Gcc/gfortran 16 released

Compilers GNU
1

FYI.

Here are the changes listed on the gcc website

  • Coarrays using native shared memory mulithreading on single node machines and handling Fortran 2018’s TEAM feature.
  • Fortran 2003: Parameterized Derived Types support is improved. Handling of LEN parameters works but still requires a future change of representation (see PR82649).
  • Fortran 2018: Support the extensions to the IMPORT statement, the REDUCE intrinsic and the new GENERIC statement.
  • The Fortran 2023 additions to the trigonometric functions are now supported (such as the sinpi intrinsic).
  • Fortran 2023: The split intrinsic subroutine is now supported and c_f_pointer now accepts an optional lower bound as a argument.
  • The -fexternal-blas64 option has been added to call external BLAS routines with 64-bit integer arguments for MATMUL. This option is only valid for 64-bit systems and when -ffrontend-optimize is in effect.

Of these the shared memory version of co-arrays is probably the biggest addition along with improved PDT support

21 Likes
2

I have tested it with a recent nightly build (see the Fortran Wiki for instructions), using two small demos computing Pi by Monte Carlo with corrays and collectives. GFortran automatically used 8 threads on my machine:

$ /usr/local/bin/gfortran -fcoarray=lib coarrays.f90 -lcaf_shmem
$ ./a.out
   3.1415699479999999 
$ /usr/local/bin/gfortran -fcoarray=lib collective.f90 -lcaf_shmem
$ ./a.out
   3.1415925240000000     
$ /usr/local/bin/gfortran --version
GNU Fortran (GCC) 16.0.1 20260405 (experimental)
Copyright © 2026 Free Software Foundation, Inc.

According to @jerryd , the option -lcaf_shmem is temporarily necessary, until an option like -fcoarray=shared is added in a later release. Note also that I had to put the option -lcaf_shmem at the end of the command for the linker.

Also tested with the GFortran 16.0.1 (20260321) already available in Fedora 44 Beta.

GFortran 16.1 should be released on April, 30th. Today it is the RC.

2 Likes
3

Also tested with my parallel Buddhabrot demo: gtk-fortran-extra/parallel_app at main · vmagnin/gtk-fortran-extra · GitHub

And note that you can set the number of images with the variable:

$ export GFORTRAN_NUM_IMAGES=8

else GFortran automatically uses the number of available cores.

1 Like
4

Thanks. I didn’t see that it was an RC on the web site. I hope the shmem version of CAF performs better than the current MPI based version which (at least on an 8 core Ryzen) doesn’t perform at all and usually “deadlocks”. I have not bothered to dig very deep into the standard CAF implementation (have used Cray’s CAF before) due to the horrendous performance (at least for me) on multi-core “single node” workstations. If the Gfortran shmem version shows a usable speedup then I hope it will lead to further adoption and improvement as more people like me finally start to use CAF.

2 Likes
5

As of last September (2025) they also added F2023 conditional expressions. (A feature Fortran should have had 60+ years ago - if only IBM had listened to John McCarthy.) Particularly with Fortran, it should be useful for simplifying handling optional arguments, where the merge intrinsic doesn’t work.

1 Like
6

Really? Which version?

I tried this very simple test:

!Test conditional expressions in Fortran 2023.
!Ref: Metcalf, 6th Ed. Section 23.2.3 Conditional expressions and arguments
!OBS: still not implemented in ifx v. 2025.3.3 and gfortran 15.2.1

program tes_conditional_expressions
implicit none
real :: x, val
call random_number(x)
print’(a,g0)', ‘x= ‘, x
val= (x > 0.5 ? x : 0.0 )
print’(a,g0)’, 'val= ', x
end program tes_conditional_expressions

Right now, the latest gfortran version distributed by Fedora repo is:

GNU Fortran (GCC) 15.2.1 20260123 (Red Hat 15.2.1-7)

And the error message is:

tes_conditional_expressions.f90:11:14:

11 | val= (x > 0.5 ? x : 0.0 )
| 1
Error:Expected a right parenthesis in expression at(1)

7

V16.

Here is a fun little test program I put together a few months ago:

program cond_expr
  implicit none

  integer :: i, ival, j
  integer, allocatable :: ivals(:), results(:)

  real, allocatable :: rvals(:)

! Use with statement function
  integer :: ce_sgn
  real :: f
  ce_sgn (f) = (f < 0.0 ? -1 :  &
                f > 0.0 ?  1 :  &
                0)

! Present vs non-present args
  ival = init (null ())
  print *, (ival == -99 ? "pass" : "fail")
  
  ival = init (42)
  print *, (ival == 42 ? "pass" : "fail")

! Simple scalar test
  ival = (.true. ? 1 : 0)
  print *, 'ival =', ival

! Nested CE in the true position, rather than the else position
  j = 4
  do, i=1,5
    ival = (i == 1 ? (j > 5 ? -1 : -5) :  &
            i == 2 ? -2 :  &
            i == 3 ? -3 :  &
                      0)
    print *, i, ival
  end do

! Earlier gfortran failure.  Now passes.
  print *, (.true. ? 1 : 0)

! Factorial
  do, i=0,10
    print *, 'factorial of', i, ' =', fact (i)
  end do

  ivals = [1, 2, 3, 4, 5, 6, 7, 8]
  results = pfact (ivals)
  print *, 'results =', results

! From McCarthy's 1959 Letter to the Editor in CACM
  i = (1 < 2  ? 4 :  &
       1 >= 2 ? 3 : 0)
  print *, 'McCarthy 1: ', (i == 4 ? "pass" : "fail")

  i = (2 < 1  ? 4 :  &
       2 > 1  ? 3 :  &
       2 > 1  ? 2 : 0)
  print *, 'McCarthy 2: ', (i == 3 ? "pass" : "fail")

  i = (2 < 1  ? 4 :  &
       .true. ? 3 : 0)
  print *, 'McCarthy 3: ', (i == 3 ? "pass" : "fail")

!  i = (2 < 1  ? 0/0 :  &
!       .true. ? 3 : 0)
!  print *, 'McCarthy 4: ', (i == undefined ? "pass" : "fail")

!  i = (2 < 1  ? 3 :  &
!       .true. ? 0/0 : 0)
!  print *, 'McCarthy 5: ', (i == undefined ? "pass" : "fail")

!  i = (2 < 1  ? 3 :  &
!       4 < 1  ? 4 : undefined)
!  print *, 'McCarthy 6: ', (i == undefined ? "pass" : "fail")

! Simulate arithmetic IF with SELECT CASE

  rvals = [-42.0, -.001, 0.0, .042, 4.2]
  do, i = 1, size (rvals)
    select case (ce_sgn (rvals(i)))
    case (-1)
      print *, rvals(i), ': negative'
    case (0)
      print *, rvals(i), ': zero'
    case (1)
      print *, rvals (i), ': positive'
    case default
      print *, rvals (i), ': should never happen'
    end select
  end do

contains

  integer function init (i)
    integer, intent(in), optional :: i

    integer :: dummy

    init = (present (i) ? i : -99)
    dummy = (present (i) ?  &
        printout ("init: arg present") :  &
        printout ("init: arg absent"))
  end function

  recursive elemental function fact (i) result (res)
    integer, intent(in) :: i
    integer :: res

    res = (i<=1 ?  &
              1 :  &
              i*fact (i-1))

  end function

  recursive pure function pfact (ia) result (res)
    integer, intent(in) :: ia(:)
    integer, allocatable :: res(:)

    if (size (ia) == 1) then
      res = fact (ia(1))
    else
      res = [fact (ia(1)), pfact (ia(2:))]
    end if

  end function

  integer function printout (s)
    character(*), intent(in) :: s
    
    print *, s
    
  end function
end program

$ gfortran --version
GNU Fortran (GCC) 16.0.1 20260410 (experimental)
Copyright (C) 2026 Free Software Foundation, Inc.
This is free software; see the source for copying conditions.  There is NO
warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

$ gfortran condexpr.f90
$ ./a.out
 init: arg absent
 pass
 init: arg present
 pass
 ival =           1
           1          -5
           2          -2
           3          -3
           4           0
           5           0
           1
 factorial of           0  =           1
 factorial of           1  =           1
 factorial of           2  =           2
 factorial of           3  =           6
 factorial of           4  =          24
 factorial of           5  =         120
 factorial of           6  =         720
 factorial of           7  =        5040
 factorial of           8  =       40320
 factorial of           9  =      362880
 factorial of          10  =     3628800
 results =           1           2           6          24         120         720        5040
 McCarthy 1: pass
 McCarthy 2: pass
 McCarthy 3: pass
  -42.0000000     : negative
  -1.00000005E-03 : negative
   0.00000000     : zero
   4.19999994E-02 : positive
   4.19999981     : positive
$
8

Right, thanks.

I’ll test it when Fedora includes it in the repo.

9

I have just created this repository with a buddhabrot example:

ppm_coarray_buddhabrot.f90 is a CLI program drawing a Buddhabrot in a portable pixmap binary format (PPM) file, a very basic uncompressed image file format. Each Fortran image is computing its own Buddhabrot, and they are finally summed using the co_sum() collective subroutine. The process is therefore very similar to what is done in astrophotography.

10

Does it mean it won’t require OpenCoarrays to build parallel programs? I’m using Homebrew for Linux to get latest gfortran (still 15.2 there) but unfortunately the opencoarrays package requires gcc@13 which seems quite out-of-date now that v16 has been released.

11

The announcement made there is for shared memory parallelism. For distributed memory parallelism with coarray one still needs OpenCoarrays to enhance gfortran (AFAIK).

12

I’m probably very wrong about this but I think OpenCoarrays is just the interface to a version of MPI thats used for the transport layer. The standard CAF syntax is built into the compiler so any backend that acts as a transport layer for communicating between processors or threads can be used to implement CAF. I think the NAG implementation of CAF is shared memory. My best guess is that the gfortran shared memory version of CAF is built on top of OpenMP or maybe some native implementation using Pthreads etc. So no I don’t think you will need OpenCoarrays unless you want to write something that can be used on a massively parallel distributed memory machine (think a Cray with thousands of cores etc). However, if I’m going to run on a Cray I would used Cray’s compilers.

13

Exactly, on single node machines, you just need to install GFortran 16.1 (just like you just need to install Intel ifx to use coarrays). I am playing with it and it works nicely.

GCC 16.1 should be released officially tomorrow. It will then arrive progressively in all packaging systems.

14

It is using a caf_shmem library:

But I don’t know what is under the hood. I am going to ask Jerry and report here.

15

Meanwhile, we can see a thread_support.c file in the tree: Making sure you're not a bot!

16

A quick look at the source code shows references to pthreads if WIN32 and CYGWYN are not defined. Does WIndows support pthreads? If so it appears to be based on pthreads. As a side note, a Fortran pthread package was written by Richard Hanson, Henry Gabb and Clay Breshears (AKA Mr. Concurrency) around 2002. Richard, Henry, Clay and I all worked for or was affiliated with the old DoD HPCMP Programming Environments and Training (PET) program at the time. Richard was working with Rice University at the time and I lent him a two processor Pentium Pro box I had put together to use as a work station until he got official access to the DoD systems. There also appears to be a more recent Fortran Pthreads library based on F2003

1 Like
17

Indeed, according to @JerryD : “The library is using pthreads if it is available”.

18

GCC16 has an Algol68 Front-End. One of the recent additions is a way to call C from Algol so Fortran can be called too. No sign of how to go the other way round.

19

Yes I saw the Algol front end mentioned on the GCC web site. There also appears to be a GCC Rust compiler under development but I don’t know enough about Rust to compare it with the standard compiler. I will say if I was going to make the effort to learn a new language it would probably be Rust. I think Microsoft has announced they are rewritting parts of Windows in Rust.

1 Like
20

Rust is definitely a nice language to learn, for discovering new programming and computing concepts and rediscovering classical ones. I have read last year that book to acquire the basics (which does not mean it is a book for beginners, it is definitely for people knowing already several languages):

And I am now deepening my understanding with:

Two books that are very well-designed.

1 Like